Sơ đồ 15:
/FILENAME, BAI TAP LON !Định nghĩa tên file
/TITLE, SO DO 15 !Đặt tiêu đề bài tính
/VIEW,1,1,1,1 !Chọn hiển thị 3D
/VUP,1,Y !Trục Y hướng lên trên
/PREP7 !Bắt đầu bài toán
!--------------------------------------------------Khai báo phần tử--------------------------------------------------------
ET,1,BEAM3 !Chọn kiểu phần tử BEAM3
!--------------------------------------------------Khai báo vật liệu--------------------------------------------------------
MP,EX,1,2E3 !Modun đàn hồi theo phương X là 2000kN/m2
MP,NUXY,1,0.3 !Hệ số poisson
!----------------------------------------------------Khai báo thông số hình học-----------------------------------------
l=1.3
b=0.04
h=0.06
A=b*h
Jz=b*h*h*h/12
R,1,A,Jz,h !Số thứ tự diện tích mặt cắt ngang, momen quan tính của mặt cắt ngang !đối với trục Oy, chiều cao mặt cắt
!--------------------------------------------------Xây dựng mô hình hình học-----------------------------------------
N,1,0,0,0 !Tọa độ nút 1(0,0,0)
N,2,l,0,0 !Tọa độ nút 2(l,0,0)
N,3,2*l,0,0 !Tọa độ nút 3(2*l,0,0)
N,4,3*l,0,0 !Tọa độ nút 4(3*l,0,0)
N,5,4*l !Tọa độ nút 5(4*l,0,0)
!------------------------------------------------Tạo mô hình phần tử hữu hạn-------------------------------------------
NPLOT !Vẽ nút
E,1,2 !Tạo phần tử gồm nút 1 và nút 2
E,2,3 !Tạo phần tử gồm nút 2 và nút 3
E,3,4 !Tạo phần tử gồm nút 3 và nút 4
E,4,5 !Tạo phần tử gồm nút 4 và nút 5
EPLOT !Vẽ phần tử
!--------------------------------------------------Điều kiện biên-----------------------------------------------------------
D,2,UY,0 !Gối cố định tại nút 2
D,2,UX,0 !Gối cố định tại nút 2
D,5,UY,0 !Gối di động tại nút 5
!--------------------------------------------------Đặt tải trọng-------------------------------------------------------------
F,4,MZ,17.238 !Momen MZ tại nút 1 là 17.238kN.m
SFBEAM,1,1,PRES,0,4.25 !Lực phân bố hình thang 0 - 4.25kN/m tại phần tử 1
SFBEAM,2,1,PRES,4.25,8.5 !Lực phân bố hình thang 4.25 - 8.5kN/m tại phần tử 2
F,1,FY,15.47 !Lực tập trung 15.47kN tại nút 1, theo phương Oy
FINISH
!------------------------------------------------------Tính toán-------------------------------------------------------------
/SOLU
ANTYPE,STATIC,NEW !Kiểu phân tích tĩnh, mới
SOLVE !Thực hiện tính toán
FINISH !Kết thúc tính toán
!---------------------------------------------------Xem kết quả------------------------------------------------------------
/POST1
!----------------------------------------------------Vẽ biểu đồ nội lực QX-----------------------------------------------
ETABLE,QXI,SMISC,1
ETABLE,QXJ,SMISC,7
PLLS,QXI,QXJ
!---------------------------------------------------Vẽ biểu đồ nội lực QY------------------------------------------------
ETABLE,QYI,SMISC,2
ETABLE,QYJ,SMISC,8
PLLS,QYI,QYJ
!---------------------------------------------------Vẽ biểu đồ nội lực MZ------------------------------------------------
ETABLE,MZI,SMISC,6
ETABLE,MZJ,SMISC,12
PLLS,MZI,MZJ
FINISH